Процедуры и функции Delphi
Изучив основные "кирпичики", из которых составляются программные инструкции, а именно - переменные и операторы, мы можем приступить к исследованию вопросов их эффективного расположения в теле программы. Для этих целей рассмотрим вопрос использования подпрограмм.
О подпрограммах в Object Pascal
Важной составной частью программирования в Object Pascal является использование подпрограмм - специальным образом оформленных и логически законченных блоков инструкций. Подпрограмму можно вызывать любое число раз из других мест программы, или из других подпрограмм. Таким образом, использование подпрограмм позволяет сделать исходный код более стройным и наглядным.
Структура подпрограммы похожа на программу в миниатюре: она содержит заголовок, блок объявления переменных и блок инструкций. Из отличий можно выделить лишь невозможность подключать модули (блок uses), а так же ограничения на объявления типов данных: если локальные простые и даже составные типы в подпрограммах вполне допустимы, то более сложные типы - объекты, классы и интерфейсы, локальными быть не могут, а потому в подпрограммах их объявлять нельзя.
Использование подпрограммы состоит из 2 этапов: сначала подпрограмму описывают, а затем, уже в блоке инструкций программы, вызывают. Отметим, что в библиотеке Delphi имеется описание тысяч готовых подпрограмм, описывать которые, разумеется, уже не надо. А их вызовом мы уже неоднократно занимались - достаточно взглянуть на любой пример, где мы встречали инструкции, подобные таким:
write('Hello, world!');
readln;
Здесь и write, и readln - стандартные подпрограммы Object Pascal. Таким образом, с вызовом подпрограмм мы уже знакомы. Осталось узнать, как создавать собственные, или пользовательские, подпрограммы. Но прежде отметим, что все подпрограммы делятся на 2 лагеря: процедуры и функции. Мы уже использовали эти термины, и даже давали им описание, однако повторимся: процедуры - это такие подпрограммы, которые выполняют предназначенное действие и возвращают выполнение в точку вызова. Функции в целом аналогичны процедурам, за тем исключением, что они еще и возвращают результат своего выполнения. Результатом работы функции могут быть данные любого типа, включая объекты.
Вместе с тем, значение, возвращаемое функцией, можно проигнорировать, в таком случае она ничем не будет отличаться от процедуры. Разумеется, при этом функция все-таки должна выполнить какое-либо действие, сказывающееся на выполнении программы, иначе она потеряет всякий смысл. С другой стороны, процедуры могут возвращать значения через свои параметры - например, как это делает DecodeDate. Таким образом, различия между процедурами и функциями в современном программировании весьма призрачны.
Как процедурам, так и функциям могут передаваться данные для обработки. Делается это при помощи списка параметров. Список параметров в описании подпрограммы и список аргументов, указываемых при ее вызове должен совпадать. Иначе говоря, если в описании определено 2 параметра типа Integer, то, вызывая такую подпрограмму, в качестве аргументов так же следует указать именно 2 аргумента и именно типа Integer или совместимого (скажем, Word или Int64).
ПРИМЕЧАНИЕ
На самом деле, Object Pascal позволяет довольно гибко обращаться с аргументами, для чего имеются различные методы, включая "перегружаемые" функции, значения параметров по умолчанию и т.д. Тем не менее, в типичном случае, количество, тип, и порядок перечисления аргументов при объявлении и при вызове процедуры или функции, должны совпадать.
Любые подпрограммы выполняются до тех пор, пока не будет выполнена последняя инструкция в блоке подпрограммы, или пока в ее теле не встретится специальная процедура exit. Процедура exit досрочно прерывает выполнение подпрограммы и возвращает управление инструкции, следующей за вызовом данной подпрограммы.
Процедуры
Итак, начнем исследование подпрограммы с процедур. Как уже было отмечено, процедуру надо описать. Описание процедуры состоит из заголовка и тела процедуры.
Заголовок состоит из ключевого слова procedure, за которым следует имя процедуры и, при необходимости, список параметров, заключенных в круглые скобки:
procedure <Имя> [(параметры)];
Вслед за заголовком может следовать блок объявления локальных меток, типов и переменных. Локальными они называются потому, что предназначены исключительно для этой процедуры.
ПРИМЕЧАНИЕ
Вопросы локальных и глобальных переменных, и вообще видимости в программах, будет рассмотрен позже в этой главе.
После заголовочной части следует тело процедуры, заключаемое в begin и end. Таким образом, исходный код процедуры может выглядеть примерно таким образом:
procedure TriplePrint(str: string);
var
i: integer;
begin
for i := 1 to 3 do begin
writeln('"'+str+'"');
end; // конец цикла for
end; // конец процедуры TriplePrint
Здесь мы определили процедуру TriplePrint, которая будет трижды выводить переданную ей в качестве аргумента строку, заключенную в двойные кавычки. Как видно, данная процедура имеет все составные части: ключевое слово procedure, имя, список параметров (в данном случае он всего один - строковая переменная str), блок объявления собственных переменных (целочисленная переменная i), и собственное тело, состоящее из оператора цикла for.
Для использования данной процедуры в любом месте программы достаточно написать инструкцию вызова процедуры, состоящую из имени процедуры и списка аргументов, например:
TriplePrint('Hello!!!');
Отметим так же, что рассмотренная нами процедура сама содержит вызов другой процедуры - writeln. Процедуры могут быть встроенными. Иначе говоря, объявление одной процедуры можно помещать в заголовочную часть другой. Например, наша процедура TriplePrint может иметь вспомогательную процедуру, которая будет "подготавливать" строку к выводу. Для этого перед объявлением переменной i, разместим объявление еще одной процедуры. Назовем ее PrepareStr:
procedure PrepareStr;
begin
str := '"'+str+'"';
end;
Отметим, что переменная str, хотя и не передается этой процедуре в качестве параметра, тем не менее может в ней использоваться, поскольку данная процедура является составной частью процедуры TriplePrint, внутри которой данная переменная доступна для использования.
Таким образом, мы получаем две процедуры, одна из которых (TriplePrint) может использоваться во всей программе, а другая (PrepareStr) - только внутри процедуры TriplePrint. Чтобы преимущество использования процедур было очевидно, рассмотрим их на примере программы, которая будет использовать ее неоднократно, для чего обратимся к листингу 6.1 (см. так же пример в Demo\Part1\Procs).
Листинг 6.1. Использование процедур
program procs;
{$APPTYPE CONSOLE}
procedure TriplePrint(str: string);
procedure PrepareStr;
begin
str := '"'+str+'"';
end;
var
i: integer;
begin
PrepareStr;
for i := 1 to 3 do begin
writeln(str);
end;
end; // конец процедуры TriplePrint
begin // начало тела основной программы
TriplePrint('Hello!!!'); // первый вызов TriplePrint
TriplePrint('How are you???'); // 2-й вызов
TriplePrint('Bye...'); // 3-й
readln;
end.
Очевидно, что если бы не процедура, то нам трижды пришлось бы писать цикл, свой для каждого слова. Таким образом, процедуры позволяют использовать единожды написанный код многократно, что существенно облегчает написание программ.
Функции
Подобно процедурам, описание функции состоит из заголовка и тела. Однако описание заголовка имеет 2 отличия: прежде всего, для функций используется ключевое слово function. Кроме того, поскольку функции всегда возвращают результат, завершается строка заголовка типом возвращаемого значения. Таким образом, для объявления функции мы получаем следующий синтаксис:
function <Имя> [(параметры)] : <тип результата>;Возвращаемое значение может быть любого типа, кроме файлового. Что касается дальнейшего описания функции, то оно полностью аналогично таковому для процедур. Единственным дополнением является то, что в теле функции обязательно должна присутствовать хотя бы одна операция присваивания, в левой части которой должно быть либо имя функции, либо ключевое слово result. Именно это выражение и определяет возвращаемое функцией значение.
Рассмотрим пример функции, которая будет возвращать куб числа, переданного ей в качестве аргумента:
function cube(value: integer) : integer;
result := value * value * value;
}
Здесь определена функция, имеющая параметр value типа целого числа, которое она возводит в третью степень путем троекратного умножения, и результат присваивается специальной переменной result. Таким образом, чтобы в любом месте программы вычислить значение числа в 3-й степени, достаточно написать такое выражение:
x = cube(3);
В результате выполнения этого выражения переменной x будет присвоено значение 27. Данный пример иллюстрирует использование функций в классическом случае - для явного вычисления значения переменной. Однако функции могут использоваться в выражениях и напрямую. Например, можно поставить вызов функции cube в каком-либо месте арифметического выражения подобно обычной переменной:
x := a + cube(b) / 2;
Подобно процедурам, функции так же могут быть встроенными. Кроме того, функции могут включать в себя не только локальные функции, но и процедуры. Впрочем, верно и обратное - в процедурах могут использоваться локальные функции. Например, в той же процедуре TriplePrint можно было бы использовать не процедуру, а функцию PrepareStr, которая принимала бы строку и возвращала ее же в кавычках:
procedure TriplePrint(str: string);
function PrepareStr(s: string) : string;
begin
result := '"'+s+'"';
end;
var
i: integer;
begin
for i := 1 to 3 do begin
writeln(PrepareStr(str)); // функция использована как переменная
end;
end;
Как уже отмечалось, помимо специальной переменной result, в функциях можно использовать другую автоматически объявляемую переменную, имя которой соответствует имени функции. Так, для функции cube имя переменной также будет cube:
function cube(value: integer) : integer;
cube := value * value * value;
}
В данном случае оба варианта будут вести себя полностью аналогично. Различия проявляются лишь в том случае, если использовать такую переменную в выражениях в теле функции. В подобных случаях следует использовать именно переменную result, а не имя функции, поскольку использ0овании имени функции в выражении внутри самой функции приведет к ее рекурсивному вызову.
Рекурсия
Таким образом мы подошли к теме рекурсии - вызову подпрограммы из самой себя. Это не является ошибкой, более того, целый ряд алгоритмов решить без рекурсии вообще было бы затруднительно.
Рассмотрим вопрос рекурсии на следующем примере:
function recfunc(x: integer) : integer
begin
dec(x); // функция декремента, уменьшает целое на 1
if x > 5 then x := recfunc(x);
result := 0; // возвращаемое значение тут не используется
end;
Здесь мы объявили функцию recfunc, принимающую один аргумент, и вызывающую саму себя до тех пор, пока значение этого аргумента больше 5. Хотя на первый взгляд может показаться, что такое поведение функции похоже на обычный цикл, на самом деле все работает несколько по-иному: если вы вызовите ее со значением 8, то она выдаст вам 3 сообщения в следующей последовательности: 5, 6, 7. Иначе говоря, функция вызывала саму себя до тех пор, пока значение x было больше 5, и собственно вывод сообщений начала 3-я по уровню получившейся вложенности функция, которая и вывела первое сообщение (в данном случае им стало 5, т.е. уменьшенное на единицу 6).
Чтобы представить себе более наглядно, как работает рекурсивный вызов, дополним эту функцию выводом комментариев, а так же счетчиком глубины рекурсии. Для этого мы, во-первых, задействуем возвращаемое функцией значение, а во-вторых, добавим еще один параметр, который и будет счетчиком. Результат проделанной работы приведен в листинге 6.2.
Листинг 6.2. Рекурсия с комментариями
program recurse;
{$APPTYPE CONSOLE}
function recfunc(x, depth: integer) : integer;
begin
dec(x);
if x > 5 then begin
write('Current recursion depth is: ');
write(depth);
write(', current x value is: ');
writeln(x);
inc(depth);
depth:=recfunc(x, depth);
end else writeln('End of recursive calls...');
write('Current recursion depth is: ');
write(depth);
write(', current x value is: ');
writeln(x);
dec(depth);
result := depth;
end;
begin
recfunc(8,0);
readln;
end.
Исходный код находится в Demo\Part1\Recurse, там же находится и исполняемый файл recurse.exe, результат работы которого вы можете увидеть на своем экране.
Использование параметров
Параметры в процедурах и функциях могут применяться не только по своему прямому предназначению - для передачи данных подпрограмме, но так же могут быть использованы для возвращения значений. Подобное их использование может быть вызвано, например, необходимостью получить более одного значения на выходе функции. Синтаксис объявления параметров в таком случае несколько отличается от стандартного - перед именем параметра следует использовать ключевое слово var:
procedure Circle (square: real; var radius, length: real);
Данная процедура принимает "на обработку" одно значение - площадь (square), а возвращает через свои параметры два - радиус (radius) и длину окружности (length). Практическая ее реализация может выглядеть таким образом:
procedure Circle (square: real; var radius, length: real);
begin
radius := sqrt(square / pi); // функция pi возвращает значение числа ?
length := pi * radius * 2;
end;
Теперь, чтобы воспользоваться этой функцией, следует объявить в программе 2 переменные, которые будут переданы в качестве аргументов этой процедуре и получат результаты. Их имена не важны, важно лишь, чтобы они были такого же, или совместимого типа, т.е. вещественные, например:
var r,l: real;
...
Circle(100,r,l);
После вызова функции Circle, переменные r и l получат значения радиуса и длины окружности. Остается их вывести при помощи writeln. Исходный код программы приведен в листинге 6.3.
Листинг 6.3. Процедура с параметрами
program params;
{$APPTYPE CONSOLE}
procedure Circle (square: real; var radius, length: real);
begin
//функция sqrt извлекает корень, а функция pi возвращает значение числа ?
radius := sqrt(square / pi);
length := pi * radius * 2;
end;
var
r,l: real;
begin
Circle(100,r,l);
writeln(r);
writeln(l);
readln;
end.
Запустив такую программу, можно убедиться, что она работает и выводит верные результаты, однако вид у них получается довольно-таки неудобочитаемый, например, длина окружности будет представлена как "3,54490770181103E+0001". Чтобы сделать вывод более удобным для восприятия, нам понадобится функция FloatToStrF. С ее помощью мы можем определить вывод числа на свое усмотрение, например:
FloatToStrF(r,ffFixed,12,8)
Кроме того, не помешало бы указать, где радиус, а где - длина окружности. Для этого модернизируем строки вывода результатов следующим образом:
writeln('Radius is: '+FloatToStrF(r,ffFixed,12,8));
writeln('Length is: '+FloatToStrF(l,ffFixed,12,8));
Наконец, не помешало бы сделать программу более полезной, для чего предусмотрим возможность ввода значения площади круга пользователем. В этих целях нам понадобится еще одна переменная (назовем ее s) и выражение для считывания ввода. Не помешает так же приглашение, объясняющее пользователю, что надо делать. В итоге основной блок программы получит следующий вид:
...
var
s,r,l: real;
begin
write('Input square: ');
readln(s);
Circle(s,r,l);
writeln('Radius is: '+FloatToStrF(r,ffFixed,12,8));
writeln('Length is: '+FloatToStrF(l,ffFixed,12,8));
readln;
end.
В принципе, это уже лучше, однако не помешало бы добавить обработку возможных ошибок ввода. Скажем, площадь должна быть больше 0. Проверку на то, является ли значение s больше нуля, можно производить непосредственно в основном коде программы, но в целях создания более универсального кода, вынесем ее в подпрограмму. Для этого первой инструкцией процедуры Circle должна быть проверка значения площади:
if square <= 0 then exit;
Таким образом, в случае, если введенное пользователем значение окажется нулевым или отрицательным, выполнение процедуры будет прекращено. Но возникает другой вопрос: как сообщить программе о том, что вычисления не были выполнены? Пожалуй, в данном случае следовало бы заменить процедуру функцией, которая возвращала бы истину, если вычисления произведены, и ложь в противном случае. Вот что у нас получится:
function Circle(square: real; var radius, length: real) : boolean;
begin
result := false;
if (square <= 0) then exit;
radius := sqrt(square / pi);
length := pi * radius * 2;
result := true;
end;
В начале функции мы определили возвращаемое значение как ложь. В результате, если параметр square не проходит проверку, то функция будет завершена и возвратит именно это значение. Если же проверка будет пройдена, то функция выполнится до конца, т.е. как раз до того момента, когда ее результатом станет истина.
Поскольку программа теперь может получить сведения о том, выполнились ли преобразования на основании возвращаемого функцией Circle булевского значения, остается добавить такую проверку в тело программы. В качестве условия для условного оператора в таком случае подойдет сама функция Circle (на самом деле, условием будет выступать не функция, а как раз возвращаемое ей значение):
if Circle(s,r,l) then begin
// вывод
end else // сообщить об ошибке
Результатом проделанной работы будет программа, приведенная в листинге 6.4. Она же находится в Demo\Part1\Params.
Листинг 6.4. Функция с параметрами
program params;
{$APPTYPE CONSOLE}
uses sysutils; //этот модуль соджержит функцию FloatToStrF
function Circle(square: real; var radius, length: real) : boolean;
begin
result := false;
if (square <= 0) then exit;
radius := sqrt(square / pi);
length := pi * radius * 2;
result := true;
end;
var
s,r,l: real;
begin
write('Input square: ');
readln(s);
if Circle(s,r,l) then begin
writeln('Radius is: '+FloatToStrF(r,ffFixed,12,8));
writeln('Length is: '+FloatToStrF(l,ffFixed,12,8));
end else writeln('Data is out of range!');
readln;
end.
Итак, при помощи ключевого слова var в списке параметров подпрограммы мы можем добиться использования передаваемых аргументов в том блоке, где был произведен вызов данной подпрограммы. В несколько другом аспекте используется ключевое слово const. Фактически, оно объявляет локальную константу, т.е. значение, которое нельзя изменять внутри данной процедуры или функции. Это бывает полезным в том случае, когда такое изменение недопустимо по логике программы и служит гарантией того, что такое значение не будет изменено.
При этом открывается еще одна возможность, связанная с константами, а именно - использование предопределенных значений. Например, можно определить функцию следующим образом:
function MyBetterFunc(val1: integer; const val2: integer = 2);
begin
result := val1*val2;
end;
Обращение же к такой функции может иметь 2 варианта: с указанием только одного аргумента (для параметра val1), или же с указанием обоих:
x := MyBetterFunc(5); // получим 10
x := MyBetterFunc(5,4); // получим 20
Оба вызова будут верными, просто в первом случае для второго параметра будет использовано значение, заданное по умолчанию.
Области видимости
Еще одной важной деталью, касающейся использования подпрограмм, является видимость переменных. Само понятие видимости подразумевает под собой тот факт, что переменная, объявленная в одном месте программы может быть доступна, или наоборот, недоступна, в другом. Прежде всего, это касается подпрограмм: как мы уже успели отметить, переменные, объявленные в заголовке процедур или функций, только в данной процедуре (функции) и будут доступны - на то они и называются локальными:
program Project1;
procedure Proc1;
var
a: integer;
begin
a := 5; //верно. Локальная переменная a здесь видна
end;
begin
a := 10; //Ошибка! Объявленная в процедуре Proc1 переменнаая здесь не видна
end.
В то же время переменные, объявленные в основном заголовке программы, доступны во всех входящих в нее подпрограммах. Потому они и называются глобальными. Единственное замечание по этому поводу состоит в том, что глобальная переменная должна быть объявлена до функции, т.е. выше ее по коду программы:
program Project2;
var
a: integer; // глобальная переменная a
procedure Proc1;
begin
a := 5; // верно
b := 10; // Ошибка! Переменая b на этот момент еще не объявлена
end;
var
b: integer; // глобальная переменная b
begin
a := 10; // верно
b := 5; // тоже верно. Здесь видны все г var
a: integer; // глобальная переменная
end.
Теперь рассмотрим такой вариант, когда у нас имеются 2 переменных с одним и тем же именем. Разумеется, компилятор еще на стадии проверки синтаксиса не допустит, чтобы в программе были объявлены одноименные переменные в рамках одного диапазона видимости (скажем, 2 глобальных переменных X, или 2 локальных переменных X в одной и той же подпрограмме). Речь в данном случае идет о том, что произойдет, если в одной и той же программе будет 2 переменных X, одна - глобальная, а другая - локальная (в какой-либо подпрограмме). Если с основным блоком программы все ясно - в нем будет присутствовать только глобальная X, то как быть с подпрограммой? В таком случае в действие вступает правило близости, т.е. какая переменная ближе (по структуре) к данному модулю, та и есть верная. Применительно к подпрограмме ближней оказывается локальная переменная X, и именно она будет задействована внутри подпрограммы.
program Project3;
var
X: integer;
procedure Proc1;
var
X: integer;
begin
X := 5; // Здесь значение будет присвоено локальной переменной X
end;
begin
X := 10; // Здесь же значение будет присвоено голобальной переменной X
end.
Таким образом, мы внесли ясность в вопрос видимости переменных. Что касается видимости подпрограмм, то она определяется аналогичным образом: подпрограммы, объявленные в самой программе, видны всюду. Те же подпрограммы, которые объявлены внутри процедуры или функции, доступны только внутри нее:
program Project1;
procedure Proc1;
procedure SubProc;
begin
end;
begin
SubProc; // Верно. Вложенная процедура здесь видна.
end;
begin
Proc1; // Верно. Процедура Proc1 объявлена в зоне глобальной видимости
SubProc; // Ошибка! Процедура SubProc недоступна за пределами Proc1.
end.
Наконец в том случае, когда имена встроенной и некой глобальной процедуры совпадают, то, по аналогии с переменными, в области видимости встроенной процедуры, именно она и будет выполнена.
Видимость в модулях
Все то, что мы уже рассмотрели, касалось программ, умещающихся в одном единственном файле. На практике же, особенно к тому моменту, когда мы перейдем к визуальному программированию, программы будут включать в себя множество файлов. В любом случае, программа на Object Pascal будет иметь уже изученный нами файл проекта - dpr, или основной модуль программы. Все прочие файлы будут располагаться в других файлах, или модулях (units), с типичным для Pascal расширением pas. При объединении модулей в единую программу возникает вопрос видимости переменных, а так же процедур и функций в различных модулях.
Для начала вернемся к рассмотрению структуры модуля, которая имеет ряд отличий от структуры программы. Итак, в простейшем случае, модуль состоит из названия, определяемого при помощи ключевого слова unit, и 2 секций - interface и implementation. Так вот как раз первая секция, interface, и служит для определения (декларации) типов данных, переменных, функций и процедур данного модуля, которые должны быть доступны за пределами данного модуля.
Чтобы лучше в этом разобраться, создадим программу, состоящую из 2 модулей - основного (dpr) и дополнительного (pas). Для этого сначала создайте новый проект типа Console Application, а затем добавьте к нему модуль, для чего из подменю File ' New выберите пункт Unit. После этого сохраните проект, щелкнув по кнопке Save All (или File ' Save All). Обратите внимание, что первым будет предложено сохранить не файл проекта, а как раз файл дополнительного модуля. Назовем его extunit.pas, а сам проект - miltiunits (см. Demo\Part1\Visibility). При этом вы увидите, что в части uses файла проекта произошло изменение: кроме постоянно добавляемого модуля SysUtils, появился еще один модуль - extunit, т.е. код стал таким:
uses
SysUtils,
extunit in 'extunit.pas';
Мы видим, что Delphi автоматически добавила пояснение, в каком файле находится подключаемый модуль. Это вызвано тем, что если о расположении собственных модулей Delphi все известно, то пользовательские модули могут находиться где угодно на жестком диске ПК. Но в данном случае мы сохранили и файл программы, и подключаемый модуль в одном каталоге, следовательно, их пути совпадают, и данное указание можно было бы опустить:
uses
SysUtils, extunit;
Тем не менее, оставим код как есть, и приступим к разработке модуля extunit. В нем, в части implementation, напишем 2 процедуры - ExtProc1 и ExtProc2. Обе они будут делать одно и то же - выводить строку со своим названием. Например, для первой:
writeln('ExtProc1');
Теперь вернемся к главному модулю программы и попробуем обратиться к процедуре ExtProc1:
...
begin
ExtProc1;
end.
Попытка компиляции или запуска такой программы приведет к ошибке компилятора "Undeclared identifier", что означает "неизвестный идентификатор". И действительно, одного лишь описания процедуры недостаточно, чтобы она была доступна вне своего модуля. Так что перейдем к редактированию extunit и в секции interface напишем строку:
procedure ExtProc1;
Такая строка, помещенная в секцию interface, является объявлением процедуры ExtProc1, и делает ее видимой вне данного модуля. Отметим, что в секции interface допускается лишь объявлять процедуры, но не определять их (т.е. тело процедуры здесь будет неуместно). Еще одним полезным эффектом от объявления процедур является то, что таким образом можно обойти такое ограничение, как необходимость определения подпрограммы до ее вызова. Иначе говоря, поскольку в нашем файле уже есть 2 процедуры, ExtProc1и ExtProc2, причем они описаны именно в таком порядке - сначала ExtProc, а потом ExtProc2, то выведя объявление ExtProc2 в interface, мы сможем обращаться к ExtProc2 из ExtProc1, как это показано в листинге 6.5:
Листинг 6.5. Объявление процедур в модуле
unit extunit;
interface
procedure ExtProc1;
procedure ExtProc2;
implementation
procedure ExtProc1;
begin
writeln('ExtProc1');
ExtProc2; // Если объявления не будет, то компилятор выдаст ошибку
end;
procedure ExtProc2;
begin
writeln('ExtProc2');
end;
end.
Отметим, что теперь процедуры ExtProc2, так же, как и ExtProc1, будет видна не только по всему модулю extunit, но и во всех использующей этот модуль программе multiunits.
Разумеется, все, что было сказано о процедурах, верно и для функций. Кроме того, константы и переменные, объявленные в секции interface, так же будут видны как во всем теле модуля, так и вне него. Остается лишь рассмотреть вопрос пересечения имен, т.е. когда имя переменной (константы, процедуры, функции) в текущем модуле совпадает с таковым в подключенном модуле. В этом случае вновь вступает в силу правило "кто ближе, тот и прав", т.е. будет использоваться переменная из данного модуля. Например, если в extunit мы объявим типизированную константу Z, равную 100, а в multiunits - одноименную константу, равную 200, то обратившись к Z из модуля extunit, мы получим значение 100, а из multiunits - 200.
Если же нам в multiunits непременно понадобится именно та Z, которая находится в модуле extunit, то мы все-таки можем к ней обратиться, для чего нам пригодится точечная нотация. При этом в качестве имени объекта указывают название модуля:
extunit.Z;
Именно таким образом можно явно ссылаться на переменные, функции и процедуры, находящиеся в других модулях.
Некоторые стандартные функции
В Object Pascal, как уже отмечалось, имеются огромное количество стандартных процедур и функций, являющихся составной частью языка, и с некоторыми мы уже знакомы (например, приведенные в табл. 5.1 и 5.2 функции преобразования). Детальное описание всех имеющихся в Object Pascal процедур и функций можно получить в справочной системе Delphi, однако мы все-таки рассмотрим здесь некоторые из них, чтобы составить общее представление - см. таблицу 6.1.
| Синтаксис | Группа | Модуль | Описание |
|---|---|---|---|
| function Abs(X); | арифметические | System | Возвращает абсолютное значение числа |
| procedure ChDir(const S: string); | управления файлами | System | Изменяет текущий каталог |
| function Concat(s1 [, s2,..., sn]: string): string; | строковые | System | Объединяет 2 и более строк в 1 |
| function Copy(S; Index, Count: Integer): string; | строковые | System | Возвращает часть строки |
| function Cos(X: Extended): Extended; | тригонометрические | System | Вычисляет косинус угла |
| procedure Delete(var S: string; Index, Count: Integer); | строковые | System | Удаляет часть строки |
| function Eof(var F): Boolean; | ввод-вывод | System | Проверяет, достигнут ли конец файла |
| procedure Halt [ ( Exitcode: Integer) ]; | управления | System | Инициирует досрочное прекращение программы |
| function High(X); | диапазона | System | Возвращает максимальное значение из диапазона |
| procedure Insert(Source: string; var S: string; Index: Integer); | строковые | System | Вставляет одну строку в другую |
| function Length(S): Integer; | строковые | System | Возвращает длину строки или количество элементов массива |
| function Ln(X: Real): Real; | арифметические | System | Возвращает натуральный логарифм числа (Ln(e) = 1) |
| function Low(X); | диапазона | System | Возвращает минимальное значение из диапазона |
| procedure New(var P: Pointer); | размещения памяти | System | Создает новую динамическую переменную и назначает указатель для нее |
| function ParamCount: Integer; | командной строки | System | Возвращает количество параметров командной строки |
| function ParamStr(Index: Integer): string; | командной строки | System | Возвращает указанный параметр из командной строки |
| function Pos(Substr: string; S: string): Integer; | строковые | System | Ищет вхождение указанной подстроки в строку и возвращает порядковый номер первого совпавшего символа |
| procedure RmDir(const S: string); | ввод-вывод | System | Удаляет указанный подкаталог (должен быть пустым) |
| function Slice(var A: array; Count: Integer): array; | разные | System | Возвращает часть массива |
| function UpCase(Ch: Char): Char; | символьные | System | Преобразует символ в верхний регистр |
| function LowerCase(const S: string): string; | строковые | SysUtils | Преобразует ASCII-строку в нижний регистр |
| procedure Beep; | разные | SysUtils | Инициирует системный сигнал |
| function CreateDir(const Dir: string): Boolean; | управления файлами | SysUtils | Создает новый подкаталог |
| function CurrentYear: Word; | даты и времени | SysUtils | Возвращает текущий год |
| function DeleteFile(const FileName: string): Boolean; | управления файлами | SysUtils | Удаляет файл с диска |
| function ExtractFileExt(const FileName: string): string; | имен файлов | SysUtils | Возвращает расширение файла |
| function FileExists(const FileName: string): Boolean; | управления файлами | SysUtils | Проверяет файл на наличие |
| function IntToHex(Value: Integer; Digits: Integer): string; | форматирования чисел | SysUtils | Возвращает целое в шестнадцатеричном представлении |
| function StrPCopy(Dest: PChar; const Source: string): PChar; | строковые | SysUtils | Копирует Pascal-строку в C-строку (PChar) |
| function Trim(const S: string): string; | строковые | SysUtils | Удаляет начальные и конечные пробелы в строке |
| function TryStrToInt(const S: string; out Value: Integer): Boolean; | преобразования типов | SysUtils | Преобразует строку в целое |
| function ArcCos(const X: Extended): Extended; | тригонометрические | Math | Вычисляет арккосинус угла |
| function Log2(const X: Extended): Extended; | арифметические | Math | Возвращает логарифм по основанию 2 |
| function Max(A,B: Integer): Integer; | арифметические | Math | Возвращает большее из 2 чисел |
| function Min(A,B: Integer): Integer; | арифметические | Math | Возвращает меньшее из 2 чисел |
Те функции, которые имеются в модуле System, являются основными функциями языка, и для их использования не требуется подключать к программе какие-либо модули. Все остальные функции и процедуры можно назвать вспомогательными, и для их использования следует подключить тот или иной модуль, указав его в uses, например, как это делает Delphi уже при создании новой программы с SysUtils:
uses: SysUtils;
Что касается практического применения той или иной функции, то оно определяется, прежде всего, той группой, к которой данная функция относится. Например, арифметические функции используются для различных математических расчетов, строковые используются для манипуляций со строками и т.д. Разумеется, в каждой категории имеется множество других функций, помимо тех, что приведены в таблице 6.1, однако по ней можно получить общее представление о том, что есть в распоряжении Delphi-программиста.
Функции в действии
В целом мы уже ознакомились с несколькими десятками предопределенных процедур и функций, а так же умеем создавать собственные. Пора применить полученные знания на практике, для чего вновь вернемся к программе, рассмотренной в главе, посвященной операторам - игре "Угадай-ка". В ней, по сути, был реализован только один из рассмотренных в самом начале книги алгоритмов - угадывания числа. Что касается алгоритма управления, то на тот момент мы оставили его без внимания.
Но прежде, чем вносить в программу изменения, определимся с тем, что мы все-таки хотим получить в итоге. Допустим, что мы хотим сделать следующие вещи:
- Реализовать-таки возможность повторного прохождения игры без перезапуска программы;
- Добавить немного "геймплея". Иначе говоря, введем уровни сложности и подсчет очков. Новые уровни можно реализовать как повторное прохождение игры с увеличением сложности (скажем, за счет расширения диапазона загадываемых значений);
- В продолжение п. 2 добавить еще и таблицу рекордов, которая будет сохраняться на диске.
Поскольку часть работы уже выполнена, то для того, чтобы приступить к разработке новой версии игры (назовем ее "Угадай-ка 2.0"), мы не будем как обычно создавать новый консольный проект в Delphi, а откроем уже существующий (Ugadaika) и сохраним его под новым именем, скажем, Ugadaika2, и в новом каталоге. Таким образом, мы уже имеем часть исходного кода, отвечающую за угадывание, в частности, цикл while (см. листинг 4.5). Этот фрагмент логичнее всего выделить в отдельную процедуру, вернее даже функцию, которая будет возвращать число попыток, сделанное пользователем. Для этого создадим функцию, которая будет принимать в качестве аргумента число, которое следует угадать, а возвращаемым значением будет целое, соответствующее числу попыток. Ее объявление будет таким:
function GetAttempts(a: integer):integer;
Данная функция так же должна иметь в своем распоряжении переменную, необходимую для ввода пользователем своего варианта ответа. Еще одна переменная нужна для подсчета результата, т.е. количества попыток. В качестве первой можно было бы использовать глобальную переменную (b), однако во избежание накладок, для локального использования в функции следует использовать локальную же переменную. Что касается переменной-счетчика, то для нее как нельзя лучше подходит автоматическая переменная result. Еще одним изменением будет использование цикла repeat вместо while. Это вызвано тем, что с одной стороны, тем, что хотя бы 1 раз пользователь должен ввести число, т.е. условие можно проверять в конце цикла, а с другой мы можем избавиться от присвоения лишнего действия, а именно - присвоения заведомо ложного значения переменной b. Ну и еще одно дополнение - это второе условие выхода, а именно - ограничение на число попыток, которое мы установим при помощи константы MAXATTEMPTS:
const MAXATTEMPTS = 10;
В результате код функции получится таким, как представлено в листинге 6.6.
Листинг 6.6. Функция GetAttempts
function GetAttempts(a: integer):integer;
var
b: integer;
begin
Result:=0;
repeat
inc(Result); // увеличиваем счетчик числа попыток
write(#13+#10+'?:');
read(b);
if (b>a) then begin
write('Too much!');
continue;
end;
if (b<a) then begin
write('Too little!');
continue;
end;
until (a=b) or (result=10); // цикл repeat выполняется пока условие ложно
end;
Теперь, когда подготовительная работа сделана, можно браться за реализацию намеченных изменений. Прежде всего, в теле программы нам потребуется цикл, который как раз и будет обеспечивать логику исполнения программы. Для него нам так же понадобятся переменные. В частности, нужны счетчик цикла, устанавливающий текущий уровень сложности, так же нужны переменные для хранения набранных очков и числа попыток, и, кроме того, не помешает заранее определить файловую переменную для таблицы рекордов и строковую - для ввода имени "рекордсмена". Итого мы получаем следующий список переменных перед основным блоком программы:
var
level, score, attempt: integer;
f: TextFile;
s: string;
Теперь инициализируем счетчик псевдослучайных чисел (т.е. оставим randomize на месте) и инициализируем нулем значения счета и уровня:
score:=0;
level:=1;
Наконец, напишем цикл для основного блока программы. Этот цикл должен быть выполнен хотя бы один раз и будет продолжать выполняться до тех пор, пока число попыток в последнем уровне было меньше максимально допустимого. В результате получаем цикл repeat со следующим условием:
until attempt>=MAXATTEMPTS;
В самом цикле нам потребуется, прежде всего, выводить информацию о текущем уровне, а так же о диапазоне отгадываемых чисел. После этого надо будет получить число попыток при помощи функции GetAttempts, вычислить набранные очки и сообщить о них пользователю, после чего увеличить счетчик цикла на 1 и перейти к следующей его итерации. В результате мы получим следующий фрагмент кода:
repeat
writeln('Level '+IntToStr(level)+':');
writeln('From 0 to '+IntToStr(level*100));
attempt:=GetAttempts(random(level*100+1));
score:=score+(MAXATTEMPTS-attempt)*level;
writeln(#10+'You current score is: '+IntToStr(score));
inc(level);
until attempt>MAXATTEMPTS;
После завершения работы цикла, т.е. когда пользователь хоть раз истратит на отгадывание все 10 попыток, следует сообщить итоговый результат и сравнит его с предыдущим значением, которое следует считать из файла. Файл мы назовем records.txt, и сопоставим с переменной f:
AssignFile(f,'record.txt');
Но прежде, чем попытаться что-либо прочитать из этого файла, необходимо убедиться, что такой файл уже есть, а если нет - то создать его, записав в него некий минимальный результат.
if not FileExists('record.txt') then begin
Rewrite(f);
writeln(f,'0'); // первая строка содержит число-рекорд
writeln(f,'None'); // а вторая - имя последнего победителя
CloseFile(f);
end;
Теперь можно считать этот файл. Правда, мы упустили из виду, что нам здесь тоже нужна переменная - для считывания предыдущего рекорда. В то же время, на данный момент мы уже имеем 2 ненужных для дальнейшей работы программы переменных - attempt и level, так что вполне можно воспользоваться любой из них для этих целей. Таким образом, мы получим следующий код:
Reset(f);
readln(f, attempt);
readln(f,s);
writeln(#10+'BEST SCORE: '+IntToStr(attempt)+' by '+s);
CloseFile(f);
Ну и последнее, чего нам остается - это проверить, является ли новое значение выше рекорда, и если да - то записать новый рекорд в файл, не забыв спросить имя игрока:
if attempt<score then begin
writeln('NEW BEST SCORE!!!');
writeln('You name?:');
readln;
readln(s);
Rewrite(f);
writeln(f,score);
writeln(f,s);
CloseFile(f);
end;
Вот, собственно, и все. Полный код получившейся программы можно увидеть на листинге 6.7, или же в файле проекта в каталоге Demo\Part1\Ugadaika2.
Листинг 6.7. Программа угадай-ка, окончательный вариант
program ugadaika2;
{$APPTYPE CONSOLE}
uses
SysUtils;
const MAXATTEMPTS = 10;
function GetAttempts(a: integer):integer;
var
b: integer;
begin
Result:=0;
repeat
inc(Result);
write(#13+#10+'?:');
read(b);
if (b>a) then begin
write('Too much!');
end;
if (b<a) then begin
write('Too little!');
end;
until (a=b) or (result=MAXATTEMPTS);
end;
var
level, score, attempt: integer;
f: TextFile;
s: string;
begin
randomize;
score:=0;
level:=1;
repeat
writeln('Level '+IntToStr(level)+':');
writeln('From 0 to '+IntToStr(level*100));
attempt:=GetAttempts(random(level*100+1));
score:=score+(MAXATTEMPTS-attempt)*level;
writeln(#10+'You current score is: '+IntToStr(score));
inc(level);
until attempt>=MAXATTEMPTS;
write(#10+'TOTAL SCORE: '+IntToStr(score+level-1));
AssignFile(f,'record.txt');
if not FileExists('record.txt') then begin
Rewrite(f);
writeln(f,'0');
writeln(f,'None');
CloseFile(f);
end;
Reset(f);
readln(f,attempt);
readln(f,s);
writeln(#10+'BEST SCORE: '+IntToStr(attempt)+' by '+s);
CloseFile(f);
if attempt<score then begin
writeln('NEW BEST SCORE!!!');
writeln('You name?:');
readln;
readln(s);
Rewrite(f);
writeln(f,score);
writeln(f,s);
CloseFile(f);
end;
sleep(3000);
end.
В завершение отметим, что эта программа использует использование не только функций, но и констант, глобальных и локальных переменных, а так же циклов и операций файлового ввода-вывода. Таким образом, на текущий момент мы познакомились со всеми основами обычного, процедурного программирования. Пора двигаться дальше - к объектно-ориентированному программированию в Object Pascal!
